AFTD Auto-Formalizing Theoretical Domains

MatrixMap.exists_kraus

theoremverifiedformalizationimported Lean

MatrixMap.exists_kraus

Statement

set_option autoImplicit true in
set_option relaxedAutoImplicit true in
open MatrixMap in
variable {A B C D E F R : Type*} [Fintype A] [DecidableEq A] in
variable [CommSemiring R] [StarRing R] [Fintype B] in
theorem MatrixMap.exists_kraus (Φ : MatrixMap A B R) :
    ∃ r : ℕ, ∃ (M N : Fin r → Matrix B A R), Φ = of_kraus M N
Formalizes
QuantumInfo, `MatrixMap.exists_kraus`
Lean proof
By Alex Meiburg, from github.com/leanprover-community/physlib at e411c6e89692 (Copyright (c) 2025 Alex Meiburg. All rights reserved, Apache-2.0). Compiled here against leanprover/lean4:v4.33.1, Mathlib v4.33.1; written for leanprover/lean4:v4.34.1.
Verified
17 Oct 2026
Axioms
Classical.choiceQuot.soundpropext
Built on 6
  • MatrixMap.choi_matrix_injThe correspondence induced by MatrixMap.of_choi_matrix is injective.
  • MatrixMap.of_krausConstruct a matrix map out of families of matrices M N : Σ → Matrix B A R indexed by κ via X ↦ ∑ k : κ, (M k) * X * (N k)ᴴ
  • MatrixMapA MatrixMap is a linear map between squares matrices of size A to size B, over R.
  • MatrixMap.choi_matrixChoi matrix of a given linear matrix map. Note that this is defined even for things that aren't CPTP, it's just rarely talked about in…
  • MatrixMap.map_choi_invProves that MatrixMap.of_choi_matrix and MatrixMap.choi_matrix inverses.
  • MatrixMap.choi_map_invProves that MatrixMap.choi_matrix and MatrixMap.of_choi_matrix inverses.

Lean source view module on GitHub

set_option autoImplicit true in
set_option relaxedAutoImplicit true in
open MatrixMap in
variable {A B C D E F R : Type*} [Fintype A] [DecidableEq A] in
variable [CommSemiring R] [StarRing R] [Fintype B] in
theorem MatrixMap.exists_kraus (Φ : MatrixMap A B R) :
    ∃ r : ℕ, ∃ (M N : Fin r → Matrix B A R), Φ = of_kraus M N := by
  classical
  let K := ((B × A) × A) × B
  let M₀ : K → Matrix B A R := fun (((b, a₁), a₂), b₂) =>
    Matrix.single b a₁ (Φ (Matrix.single a₁ a₂ (1 : R)) b b₂)
  let N₀ : K → Matrix B A R := fun (((_, _), a₂), b₂) => Matrix.single b₂ a₂ (1 : R)
  let e : Fin (Fintype.card K) ≃ K := (Fintype.equivFin _).symm
  refine ⟨Fintype.card K, M₀ ∘ e, N₀ ∘ e, ?_⟩
  apply choi_matrix_inj
  ext ⟨j₁, i₁⟩ ⟨j₂, i₂⟩
  simp only [choi_matrix, of_kraus, LinearMap.coe_sum, LinearMap.coe_mk, AddHom.coe_mk,
    Finset.sum_apply]
  have hsum_reindex :
      (∑ x : Fin (Fintype.card K),
          (M₀ ∘ e) x * Matrix.single i₁ i₂ (1 : R) * ((N₀ ∘ e) x).conjTranspose) j₁ j₂
        =
      ∑ y : K, (M₀ y * Matrix.single i₁ i₂ (1 : R) * (N₀ y).conjTranspose) j₁ j₂ := by
    rw [Matrix.sum_apply]
    exact e.sum_comp
      (fun y : K => (M₀ y * Matrix.single i₁ i₂ (1 : R) * (N₀ y).conjTranspose) j₁ j₂)
  rw [hsum_reindex, Fintype.sum_prod_type, Fintype.sum_prod_type, Fintype.sum_prod_type]
  simp [M₀, N₀, Matrix.mul_apply, Matrix.single, ite_and]
  rw [Finset.sum_eq_single i₂]
  · rw [Finset.sum_eq_single j₂]
    · simp
    · intro b hb hbj
      simp [hbj, star_zero]
    · simp
  · intro a ha ha_ne
    simp [ha_ne, star_zero]
  · simp
See it in the graphDiscuss this resultChallenge it